start tok64 d64-6i0fZ2
0 POKE53280,5:POKE53281,5
1 PRINT"{black}{clear}{down}{right}please remove write protect and press{space*3}any key.
3 POKE198,.:WAIT198,1
10 tx$="commodore 64
20 PRINT"{clear}{down}{right}{reverse on}boot message:{down}{white}":PRINT"booting "tx$
21 PRINT"{black}{down}{right}do you want to change it?
22 POKE198,.:WAIT198,1:GETa$:IFa$="n"THEN30
23 PRINT"{clear}{down}{right}enter boot message:":INPUT"{home}{down*3}";tx$
30 PRINT"{clear}{down}{right}please wait{.*3}":POKE53280,4:OPEN1,8,15,"i0:":GET#1,a
40 IFa=.THEN70
50 POKE53280,2:PRINT"{down}{right}disk error has occured!":GOTO370
70 OPEN2,8,2,"#"
80 PRINT#1,"u1 2 0 18 0":PRINT#1,"b-p 2 5"
90 GET#2,a$
100 a=(ASC(a$+CHR$(.))AND1):IFa=1THEN160
110 POKE53280,3:PRINT"{clear}{down}{right}boot block is already in use!
120 PRINT"{right}{down}continue?
130 POKE198,.:WAIT198,1:GETa$:IFa$<>"y"THEN370
150 PRINT"{clear}{down}{right}please wait{.*3}":POKE53280,4
160 PRINT#1,"u1 2 0 1 0"
170 FORx=1TO3:GET#2,b$:h$=h$+b$:NEXT
190 IFh$<>"cbm"THEN260
200 POKE53280,3:PRINT"{clear}{down}{right}a boot sector is already installed!
210 PRINT"{right}{down}continue?
220 POKE198,.:WAIT198,1:GETa$:IFa$<>"y"THEN370
250 POKE53280,4:PRINT"{clear}{down}{right}please wait{.*3}":GOTO270
260 IFa=.ANDh$<>"cbm"THENPOKE53280,3:PRINT"{clear}{down}{right}sector used for program!":GOTO210
270 POKE53280,1:POKE53281,1:PRINT"{clear}{down}{right}installing sector now{.*3}
310 PRINT#1,"b-p 2 0":a$=CHR$(.)
320 PRINT#2,"cbm"a$a$a$a$tx$a$a$CHR$(76)CHR$(77)CHR$(255);
340 PRINT#1,"u2 2 0 1 0
350 IFa=1THENPRINT#1,"b-a 0 1 0
360 PRINT"{clear}{down}{right}{light blue}boot sector installed !!":qq=-1
370 CLOSE2:CLOSE1:POKE53280,14:POKE53281,6:IFqq<>-1THENPRINT"{clear}";
380 PRINT"{light blue}{down}{right}program running ended.
stop tok64
(bastext 1.0)